home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO027A.dsk / AWP.READER.bas < prev    next >
BASIC Source File  |  2012-02-16  |  1KB  |  37 lines
  1. 200  TEXT : HOME : VTAB 5
  2. 210  PRINT "This program will show you how to work with AppleWorks Word Processing files"
  3. 220  PRINT "from Applesoft BASIC programs."
  4. 230  PRINT : PRINT "Select a small Word Processing file and"
  5. 240  INPUT "enter the name: ";FL$
  6. 300  REM BS = File starting point
  7. 310 BS = 8192:HL = 300
  8. 330  PRINT  CHR$(4);"BLOAD";FL$;",A";BS;",TAWP"
  9. 335  HOME : INVERSE 
  10. 340  PRINT "Display file: ";FL$: NORMAL : POKE 34,1
  11. 345  REM Lines360-400 form main program body.
  12. 350 START = BS +HL
  13. 360 Y =  PEEK(START +1)
  14. 370  IF Y > = 208  THEN  GOSUB 1000
  15. 380  IF Y <208  THEN  GOSUB 1900
  16. 400  GOTO 360
  17. 1000  REM Handling <CR> lines and Command lines
  18. 1010  IF Y = 208  THEN  PRINT  CHR$(13): GOTO 1100
  19. 1020  IF Y = 223  THEN  PRINT "----justify----": GOTO 1100
  20. 1030  IF Y = 224  THEN  PRINT "----unjustify----": GOTO 1100
  21. 1040  IF Y = 225  THEN  PRINT "----centre----": GOTO 1100
  22. 1050  IF Y = 255  THEN  POP : TEXT : END 
  23. 1060  IF Y = 230  THEN  PRINT "----single space----": GOTO 1100
  24. 1070  IF Y = 231  THEN  PRINT "----double space----": GOTO 1100
  25. 1080  IF Y = 232  THEN  PRINT "----triple space----": GOTO 1100
  26. 1090  IF Y = 233  THEN  PRINT "----new page----"
  27. 1100 START = START +2: RETURN 
  28. 1900  REM Handle standard text
  29. 1910 SL =  PEEK(START): REM String Length
  30. 1920 Z = ( PEEK(START +3) >127)
  31. 1930  FOR I = START +4 TO START +SL +1
  32. 1935  IF ( PEEK(I) <31)  THEN 1950: REM Special chars
  33. 1940  PRINT  CHR$( PEEK(I));
  34. 1950  NEXT 
  35. 1960  IF Z  THEN  PRINT 
  36. 1970 START = START +SL +2
  37. 1980  RETURN